#Palatalisation prosodique
Feature prosody(*plain, lab, pal)
#Palatalisation inhérente
Feature inherent(*invoid, inlab, inpal)
#Ce trait n'est pertinent que pour les vélaires
Feature manner(occl, nas, fric)
Feature +affix
#On déclare des diacritiques distinctes pour prosodique et inhérente, et pour le tiret
#Elles sont sont "flottantes" pour ne pas bloquer les changements qui ne les mentionnent pas explicitement
Diacritic \- (floating) (before) [+affix]
Diacritic ᵒ (floating) (before) [lab]
Diacritic ᵉ (floating) (before) [pal]
Diacritic ᵘ (floating) [inlab]
Diacritic ⁱ (floating) [inpal]
#Ces trois symboles déclarés explicitement car digraphes
Symbol kʷ [occl inlab]
Symbol ŋʷ [nas inlab]
Symbol xʷ [fric inlab]
#Ceux-ci déclarés pour une meilleure intégration aux règles impliquant les précédents
Symbol k [occl]
Symbol ŋ [nas]
Symbol x [fric]
#Définition diphtongues
Element dipht @vow @glide
#Définition élément réunissant voyelles et diphtongues
Element sybic {@vow, @dipht}
Class cons {p, t, k, kʷ, m, n, ŋ, ŋʷ, ɸ, θ, s, x, xʷ, l, r, w, j, ʔ}
Class glide {j, w}
Class labiovelar {kʷ, ŋʷ, xʷ}
Class plainvelar {k, ŋ, x}
Class obstruent {p, t, k, kʷ, ɸ, θ, x, xʷ}
Class stop {p, t, k, kʷ}
Class fricative {ɸ, θ, x, xʷ}
Class nasal {m, n, ŋ, ŋʷ}
Class coda {m, n, ŋ, ŋʷ, s, l, r}
Class vow {a, ə}
Class root {⟨}
#On sépare les ʷ des labiovélaires des ʷʲ de début de mot/suffixe
Deromanizer:
ʷ [] => * [lab] / {@root, $} _
ʲ [] => * [pal] / {@root, $} _
ʷ&[+affix] [] => * [lab +affix]
ʲ&[+affix] [] => * [pal +affix]
#Suppression des glottales uniquement si début de racine après suffixe consonantique
hamza-black-magic:
@cons @root ʔ&[$prosody] => [$prosody] * *
Then:
@root @cons => * [+affix]
#Toutes les consonnes reçoivent un schwa sauf devant <a>
epenthesis:
* => ə / @cons _ // _ a
#Suppression schwa après diphtongue et consonne coda (sauf si seule consonne du mot)
deletion-final:
ə => * / {@coda, j, w} _ $ // $ [] _
#Suppression schwa pour former groupes initiaux autorisés (sauf si liquide termine le mot)
deletion-initial:
ə => * / $ @obstruent _ {l, r} // _ [] $
ə => * / $ s _ @stop
#Suppression schwa surnuméraires dans diphtongues
deletion-diphtongs:
ə => * / @cons _ @glide a // _ [] [] {w, j}
ə => * / @vow @glide _
#Suppression schwa pour former groupes médians autorisés (sauf si le groupe serait devant un segment final)
deletion-middle propagate ltr:
ə => * / @sybic @obstruent _ {l, r} // _ [] $
ə => * / @sybic s _ @stop // _ [] $
ə => * / @sybic @nasal _ @stop // _ [] $
ə => * / @sybic {@nasal, l, r} _ @cons&!{ʔ, @glide} // _ [] $
ə => * / @sybic @stop _ s // _ [] $
ə => * / @sybic s _ {@nasal, l, r} // _ [] $
ə => * / @sybic @cons$1 _ ~$1&!ʔ // _ [] $
ə => * / @sybic @labiovelar&[$manner] _ @plainvelar&[$manner] // _ [] $
#Voici la première règle formulée dans Lexurgy exactement comme Wojnicz l'avait formulée en clair
delabialisation:
ŋʷ => [invoid] / _ $
@labiovelar => @plainvelar / _ @cons
#D'autres segments que les vélaires reçoivent le trait "lab/pal inhérente"
inherent-lab-pal:
@cons&[invoid] j => [inpal] * / _ a
@cons&[invoid] w => [inlab] * / _ a
#Le marqueur prosodique se déplace à la fin de la racine
prosodic-marker-to-end:
[plain invoid] => [lab] / {$, [+affix]} []? [lab] [-affix]* _
[plain invoid] => [lab] / [+affix lab] [-affix]* _
[plain invoid] => [pal] / {$, [+affix]} []? [pal] [-affix]* _
[plain invoid] => [pal] / [+affix pal] [-affix]* _
#Suppression des marqueurs prosodiques situés à gauche du dernier marqueur prosodique
Then:
[!plain] => [plain] / _ []* [!plain]
#En partant de la fin chaque voyelle reçoit son marqueur prosodique sauf si elle est devant une consonne à marque inhérente ou fait partie d'une diphtongue
prosodic-marker propagate rtl:
@vow => [lab] /_ []* [lab] // {[!invoid] _, _ @glide}
@vow => [pal] /_ []* [pal] // {[!invoid] _, _ @glide}
#Ça c'est pour pas oublier de marquer les voyelle placées après les suffixes à marqueur
@vow => [lab] / [lab] _ !@glide
@vow => [pal] / [pal] _ !@glide
#Nécessaire pour effacer prosodie des diphtongues finales de racine
lab-pal-dipht:
@dipht => [plain]
#Marqueurs prosodiques après inhérents et glides, et devant consonne, supprimés
Romanizer:
@vow => [plain] / {[!invoid], @glide} _
@cons => [plain]
#On remet les diacritiques du début confondant prosodique et inhérente
Then:
* [pal] => ʲ [plain]
* [lab] => ʷ [plain]
[inpal] * => [invoid] ʲ
[inlab] * => [invoid] ʷ
#Suppression tirets
Then:
[+affix] => [-affix]
Accueil 
