Le levostis

Sujet: Re: Le levostis Lun 10 Oct 2022 - 12:04

D'accord. C'est cette transformation de la structure sous-jacente vers la structure de surface en proto-langue que la cliente doit réaliser "à la main" quand elle veut créer de nouveaux mots ? Je vais peut-être voir s'il n'est pas possible de formaliser ça dans Lexurgy.

Messages : 850 Date d'inscription : 13/12/2017

Oui, c'est ça qu'elle doit faire elle-même. J'ai lu les tutos de Lexurgy et j'ai estimé que ce serait trop difficile à programmer, mais c'était la première fois que je m'en servais, je veux bien un second avis d'un utilisateur chevronné.

Messages : 850 Date d'inscription : 13/12/2017

Je n'ai pas eu le temps de poster plus de détails hier et je n'en ai pas trop non plus ce soir, je vais commencer à détailler l'évolution, mais pas tout d'une traite.

Les premiers changements ont affecté les voyelles et les semi-voyelles, voilà ce qui est arrivé dans l'ordre:

1: Les diphtongues se sont monophtonguées:
*/əw/ > */u/
*/əj/ > */i/
*/aw/ > */ɔ/
*/aj/ > */ɛ/

2: Avant /j/ et après une consonne palatalisée, les voyelles centrales sont devenues antérieures, et avant /w/ et après une consonne labialisée, elles sont devenues postérieures:
*/ə/ > */i/
*/a/ > */ɛ/
*/ə/ > */u/
*/a/ > */ɔ/

Après ce changement, la palatalisation et la labialisation sont toujours là, mais on ne les transcrit plus par simplicité, par exemple */tʷəsəjrʷas/ donne */tusirɔs/ et pas */tʷusirʷɔs/.

3: Tous les */ə/ accentués sont devenus des */ɨ/.

4: Au début des mots, */ji/ > */i/ et */wu/ > */u/.

Le reste ne devrait pas tarder.

Sujet: Re: Le levostis Mer 12 Oct 2022 - 9:38

Wojnicz a écrit:: Tous les */ə/ accentués sont devenus des */ɨ/.

T'avais des schwas accentués ? T'as bien fait de les transformer.

_________________

Pœr æse qua stane:

Messages : 850 Date d'inscription : 13/12/2017

Oui, j'ai oublié de le mentionner, le proto-levostis accentuait toujours l'avant-dernière voyelle, comme le levostis moderne, même si c'était un schwa. J'ai envisagé de mettre un système d'accent plus complexe, mais ça ne donnait pas de bons résultats, ça empêchait souvent les voyelles longues de se former et ça créait trop de hiatus à la place.

Citation :: es uttu stora iela pó : j'ai 43 ans

Bien joué, Velonzio, tu as tout compris.

Je vais continuer un peu les changements, voici les suivants, qui ont affecté divers groupes de consonnes:

5: Après une nasale, les fricatives non-sibilantes */ɸ θ x/ sont devenues les occlusives */p t k/.

6: Les nasales précédant une occlusive ou une autre nasale sont toutes devenues homorganiques.

7: Les groupes */ms ns ŋs ts/ ont tous fusionné avec */ss/.

8: Les groupes */nl rl/ ont fusionné avec */ll/ et les groupes */sr lr/ avec */rr/.

9: Avant une liquide, les nasales */m n ŋ/ sont devenues */mb nd ŋg/ par épenthèse.

10: Après une nasale, les occlusives */p t k/ sont devenues */b d g/.

Et on est encore loin du bout.

Messages : 850 Date d'inscription : 13/12/2017

Évolution du proto-levostis, chapitre final!

11: */ŋ/ a fusionné avec */n/.

12: */ln/ a fusionné avec */nn/.

13: Entre voyelles, ou après une voyelle et avant une liquide, les fricatives */ɸ θ x s/ sont devenues */β ð ɣ z/.

14: Avant une liquide, les fricatives */β ð ɣ/ sont devenues */b d g/.

15: */w/ a fusionné avec */β/.

16: */z/ a fusionné avec */r/.

17: Avant */u ɔ/, les fricatives (simples ou géminées) */x ɣ/ ont fusionné avec */ɸ β/.

18: Les */x/ restants sont devenus des */h/ au début des mots avant une voyelle.

19: Les suites */rVr/ et */rVrr/ sont devenues */rVl/ et */rVll/ respectivement.

20: */xx/ a fusionné avec */kk/, et */x/ est devenue */k/ avant ou après une liquide.

21: Avant */l/, les occlusives */t d/ ont fusionné avec */k g/.

22: Les fricatives */θ ð/ ont fusionné avec */ɸ β/.

23: Les fricatives */ɸ β/ sont devenues */f v/.

24: */j/ a disparu avant et après */i/.

25: */ɣ/ et */ʔ/ ont disparu partout.

26: */ɨ/ a fusionné avec */i/.

27: Quand la première voyelle des suites suivantes était accentuée, les suites sont devenues des voyelles longues:
*/ii/ et */iə/ ont fusionné en /iː/
*/uə/ et */uu/ ont fusionné en /uː/
*/ɛi/, */ɛə/ er */ɛɛ/ ont fusionné en /ɛː/
*/ɛu/, */ɔə/, */ɔu/, */ɔɔ/ et */au/ ont fusionné en /ɔː/
*/aə/ et */aa/ ont fusionné en /aː/.

28: */ə/ a fusionné avec */a/.

29: Toutes les voyelles accentuées sont devenues longues quand elles étaient au contact d'une autre voyelle.

Et voici les paramètres pour Lexurgy, comme ça t'intéresse, Mardi.

Sujet: Re: Le levostis Jeu 13 Oct 2022 - 19:50

Merci bien ! Pour ma part j'ai réussi à bricoler un truc pour la syllabification et les schwas (qui fonctionne à l'envers : un schwa après chaque consonne, puis on supprime ceux qu'il faut). Là je vais m'attaquer à la palatalisation et la labialisation.

Code:: Feature (syllable) +lab
Feature (syllable) +pal

Diacritic ᵒ (floating) (before) [+lab]
Diacritic ᵉ (floating) (before) [+pal]

Element diphtong (@vow @glide)
Element Cluster (@cons @cons)
Element scluster (s {p, t, k, kʷ})
Element lcluster ({p, t, k, kʷ, ɸ, θ, x, xʷ} {l, r})
Element attack ({@scluster, @lcluster, @cons})
Element xcluster ({p, t, k, kʷ} s)
Element mcluster ({{m, n, ŋ, ŋʷ}, {l, r}} @cons)
Element smcluster (s {@nasal, l, r})
#Element geminate (@cons$1 $1)
Element legal ({@mcluster, @smcluster, @xcluster, @attack})
Element legalcluster ({@mcluster, @smcluster, @xcluster, @scluster, lcluster})

Class cons {p, t, k, kʷ, m, n, ŋ, ŋʷ, ɸ, θ, s, x, xʷ, l, r, w, j, ʔ}
Class glide {j, w}
Class labiovelar {kʷ, ŋʷ, xʷ}
Class plainvelar {k, ŋ, x}
Class obstruent {p, t, k, kʷ, ɸ, θ, x, xʷ}
Class stop {p, t, k, kʷ}
Class fricative {ɸ, θ, x, xʷ}
Class nasal {m, n, ŋ, ŋʷ}
Class coda {m, n, ŋ, ŋʷ, s, l, r}
Class vow {a, ə}
Class prosody {ʲ, ʷ}

epenthesis:
* => ə / @cons _ // _ a

deletion-final:
ə => * / {@coda, j, w} _ $

deletion-initial:
ə => * / $ @obstruent _ {l, r}
ə => * / $ s _ @stop

deletion-middle propagate ltr:
ə => * / @vow @obstruent _ {l, r} // {@legalcluster _, _ [] $}
ə => * / @vow s _ @stop // {@legalcluster _, _ [] $}
ə => * / @vow @nasal _ @stop // {@legalcluster _, _ [] $}
ə => * / @vow {@nasal, l, r} _ @cons // {@legalcluster _, _ [] $}
ə => * / @vow @stop _ s // {@legalcluster _, _ [] $}
ə => * / @vow s _ {@nasal, l, r} // {@legalcluster _, _ [] $}
ə => * / @vow @cons$1 _ $1 // {@legalcluster _, _ [] $}

deletion-diphtongs:
ə => * / @cons _ @glide a // _ [] [] {w, j}
ə => * / @vow @glide _

delabialisation:
ŋʷ => ŋ / _ $
@labiovelar => @plainvelar / _ @cons

Messages : 850 Date d'inscription : 13/12/2017

Quel boulot! Je l'ai testé, j'ai bien peur qu'il ne soit pas encore au point, mais je t'avoue que je ne saurais pas du tout corriger ça moi-même. Le problème est au niveau des consonnes labialisées, regarde, ton programme insère /ə/ entre la consonne et /ʷ/:

Citation :: θxʷŋk => θəxəʷəŋkə
ŋʷa => ŋəʷa
ŋʷɸa => ŋəʷəɸa
jsŋʷ => jəsŋəʷə
xʷra => xəʷəra
xatlaŋʷ => xatlaŋəʷə
θkʷa => θəkəʷa

Sujet: Re: Le levostis Jeu 13 Oct 2022 - 20:42

J'avais complètement oublié de tester avec ces consonnes ! Il fallait que je définisse les digraphes auparavant avec :

Code:: Symbol kʷ, ŋʷ, xʷ

avant la définition des classes, ce qui nous donne :

Code:: θxʷŋk => θəxʷəŋkə
ŋʷa
ŋʷɸa => ŋʷəɸa
jsŋʷ => jəsəŋ
xʷra => xra
xatlaŋʷ => xatlaŋ
θkʷa => θəkʷa

Messages : 850 Date d'inscription : 13/12/2017

Ça marche mieux! Il y a encore quelques endroits où ça coince un peu, mais pour d'autres raisons plus pointues:

Citation :: ʔnʔala => ʔənʔala (/ʔ/ ne peut jamais suivre une autre consonne, sauf si c'est une semi-voyelle)
xʷaŋʷakʷk => xʷaŋʷakʷəkə (comme les labiovélaires se délabialisent avant une consonne, cette suite *kʷk devrait donner /kk/)
ʔwakta => ʔwakəta (quand /a/ n'est pas suivi d'une semivoyelle, les suites /Cja/ et /Cwa/ deviennent /Cʲa/ et /Cʷa/)

Ça fait longtemps que tu te sers de Lexurgy? Tu as l'air de le connaitre sur le bout des doigts.

Sujet: Re: Le levostis Ven 14 Oct 2022 - 11:22

Wojnicz a écrit:: ʔnʔala => ʔənʔala (/ʔ/ ne peut jamais suivre une autre consonne, sauf si c'est une semi-voyelle)

Il me semblait avoir prévu le coup, mais j'ai enlevé la ligne qui s'en occupait car je pensais que les autres règles suffisaient. Sans tester bien sûr...

Wojnicz a écrit:: xʷaŋʷakʷk => xʷaŋʷakʷəkə (comme les labiovélaires se délabialisent avant une consonne, cette suite *kʷk devrait donner /kk/)

Ainsi la délabialisation arrive avant la syllabification ? Je vais changer l'ordre des règles. Par exemple, il faudrait obtenir ŋʷɸa => ŋəɸa ?

Wojnicz a écrit:: ʔwakta => ʔwakəta (quand /a/ n'est pas suivi d'une semivoyelle, les suites /Cja/ et /Cwa/ deviennent /Cʲa/ et /Cʷa/)

Je n'ai pas encore touché à +lab et +pal inhérents et prosodiques, faudra que je distingue les deux d'une manière ou d'une autre.

Wojnicz a écrit:: Ça fait longtemps que tu te sers de Lexurgy? Tu as l'air de le connaitre sur le bout des doigts.

Je l'emploie exclusivement depuis que je l'ai découvert dix-huit mois plus tôt, suivant son développement de près (et même suggéré deux-trois améliorations au créateur), ça me permet de ne pas trop oublier comment ça fonctionne. Et cette semaine j'avais du temps pour le faire.

Messages : 850 Date d'inscription : 13/12/2017

Citation :: Ainsi la délabialisation arrive avant la syllabification ? Je vais changer l'ordre des règles. Par exemple, il faudrait obtenir ŋʷɸa => ŋəɸa ?

Non, *ŋʷɸa donnerait /ŋʷəɸa/, la délabialisation a lieu au moment de la syllabification, on considère que si une suite de consonnes commence par une labiovélaire, c'est comme si elle était vélaire simple, et on accepte les mêmes groupes qu'avec une "vraie" vélaire. Exemples:
*ŋɸa > /ŋəɸa/
*ŋʷɸa > /ŋʷəɸa/, comme il y a un schwa, la labialisation se manifeste
*aŋɸ > /aŋɸə/, comme la suite /ŋɸ/ est autorisée au milieu des mots
*aŋʷɸ > /aŋɸə/ aussi, si on a /ŋʷɸ/ dans une position où la suite /ŋɸ/ serait permise, alors elle devient /ŋɸ/, pas de schwa, plus de labialisation

Si on a *xʷaŋʷakk, ça donne /xʷaŋʷakkə/, eh bien c'est pareil avec *xʷaŋʷakʷk, ça donne aussi /xʷaŋʷakkə/ car on ignore la labialisation le temps de faire la syllabification, puis on la remet s'il y a une voyelle après.

Sujet: Re: Le levostis Ven 14 Oct 2022 - 13:21

Voici, une véritable usine à gaz, pas du tout le truc élégant dont j'avais rêvé, un jour je verrai s'il n'est pas possible d'optimiser... En attendant il reste sûrement encore des erreurs.

Code:: Feature +lab, +pal
Feature +inlab, +inpal
Feature manner(occl, nas, fric)

Diacritic ᵒ (floating) (before) [+lab]
Diacritic ᵉ (floating) (before) [+pal]
Diacritic ᵘ [+inlab]
Diacritic ⁱ [+inpal]

Symbol kʷ [occl +inlab]
Symbol ŋʷ [nas +inlab]
Symbol xʷ [fric +inlab]
Symbol k [occl]
Symbol ŋ [nas]
Symbol x [fric]

Class cons {p, t, k, kʷ, m, n, ŋ, ŋʷ, ɸ, θ, s, x, xʷ, l, r, w, j, ʔ}
Class glide {j, w}
Class labiovelar {kʷ, ŋʷ, xʷ}
Class plainvelar {k, ŋ, x}
Class obstruent {p, t, k, kʷ, ɸ, θ, x, xʷ}
Class stop {p, t, k, kʷ}
Class fricative {ɸ, θ, x, xʷ}
Class nasal {m, n, ŋ, ŋʷ}
Class coda {m, n, ŋ, ŋʷ, s, l, r}
Class vow {a, ə}

Deromanizer:
@plainvelar ʷ => @labiovelar *
ʷ [] => * [+lab] / {\-, $} _
ʲ [] => * [+pal] / {\-, $} _

epenthesis:
* => ə / @cons _ // _ a

deletion-final:
ə => * / {@coda, j, w} _ $

deletion-initial:
ə => * / $ @obstruent _ {l, r}
ə => * / $ s _ @stop&!ʔ

deletion-middle propagate ltr:
ə => * / @vow @obstruent _ {l, r} // _ [] $
ə => * / @vow s _ @stop&!ʔ // _ [] $
ə => * / @vow @nasal _ @stop // _ [] $
ə => * / @vow {@nasal, l, r} _ @cons&!ʔ // _ [] $
ə => * / @vow @stop _ s // _ [] $
ə => * / @vow s _ {@nasal, l, r} // _ [] $
ə => * / @vow @cons$1 _ $1 // _ [] $
ə => * / @vow @labiovelar _ @plainvelar // _ [] $

deletion-diphtongs:
ə => * / @cons _ @glide a // _ [] [] {w, j}
ə => * / @vow @glide _

delabialisation:
ŋʷ => ŋ / _ $
@labiovelar => @plainvelar / _ @cons

inherent-lab-pal:
@cons j => [+inpal] * / _ a
@cons w => [+inlab] * / _ a

prosodic-pal-lab-to-end:
[-lab -pal -inpal -inlab] => [+lab] / $ [+lab] []* _ $ // {[+lab], [+pal]} _
[-lab -pal -inpal -inlab] => [+pal] / $ [+pal] []* _ $ // {[+lab], [+pal]} _

prosodic-lab-pal propagate rtl:
@vow => [+lab] /_ []* [+lab] // {{[+inlab], [+inpal]} _, _ @glide}
@vow => [+pal] /_ []* [+pal] // {{[+inlab], [+inpal]} _, _ @glide}
@vow => [+lab] / [+lab] _ $
@vow => [+pal] / [+pal] _ $

Romanizer:
@cons => [-pal -lab]
@vow => [-pal -lab] / {[+inlab], [+inpal]} _
\- => *
Then:
* [+pal] => ʲ [-pal]
* [+lab] => ʷ [-lab]
[+inpal] * => [-inpal] ʲ
[+inlab] * => [-inlab] ʷ

(On peut écrire les protoformes avec les tirets des affixes, comme t-sjra-ʷs)

Messages : 850 Date d'inscription : 13/12/2017

J'ai fait un test avec une centaine de racines, ça a marché avec 85% d'entre elles! Les fois où ça a raté, ça a donné ça:

Le programme n'ajoute pas de schwa après certaines consonnes dans les racines consistant en une consonne unique, ça n'arrive qu'avec celles qui peuvent apparaitre en fin de mot. Le programme ne comprend pas que pour apparaitre en dernière position, ces consonnes ont besoin d'être précédées d'une voyelle.

Citation :: ʲm => m
ʷs => s
ŋʷ => ŋ

Ça devrait donner /mʲə sʷə ŋʷə/.

Il y a un problème similaire avec les groupes de consonnes autorisés en début de mot contenant une liquide, comme la liquide peut apparaitre en fin de mot et que le groupe peut apparaitre en début de mot, le programme considère qu'il n'y a rien à rajouter.

Citation :: ʲkʷr => kr

Ça devrait donner /kʷər/.

Après une voyelle, si une labiovélaire précède une vélaire simple, le programme la délabialise toujours même si ça donne un groupe proscrit (je mets ceux que j'ai eu en gras pour qu'ils soient plus visibles), dans quel cas il ne l'épenthétise pas.

Citation :: ʲkʷaxʷŋakʷ => kʷaxŋʲakʷə
ʷmakxʷk => mʷakʷəxkʷə

Ça devrait donner /kʷaxʷəŋʲakʷə mʷakʷəxʷəkʷə/.

Le programme tente de labialiser ou de palataliser les semivoyelles alors ce que n'est pas possible.

Citation :: ʲwaka => wʲakʲa
ʷwkaɸwa => wʷəkʷaɸʷa
ʷwa => wʷa
ʲwa => wʲa
ʲwakʷa => wʲakʷa
ʲjŋm => jʲəŋʲəm
ʲwakʷ => wʲakʷə

Quand une suite *Cja ou *Cwa suit directement un marqueur de prosodie, ça donne /Cⁱa/ et /Cᵘa/ au lieu de /Cʲa/ et /Cʷa/, de plus le marqueur de prosodie n'est pas effacé.

Citation :: ʲtwa => ʲtᵘa
ʲrwark => ʲrᵘarkʲə

Mais ça reste un excellent boulot, je t'en remercie, tu n'avais vraiment pas besoin de te donner autant de mal!

Citation :: une véritable usine à gaz

C'est ce que je m'étais dit en lisant les tutos de Lexurgy, que le système serait peut-être possible à programmer mais que ce serait une telle usine à gaz que ça ne vaudrait pas le coup. D'ailleurs, je te tiens pour un fou d'avoir essayé ^^!

Sujet: Re: Le levostis Sam 15 Oct 2022 - 16:33

Coucou me revoici, j'étais incapable de passer à autre chose alors j'ai revisité tous les problèmes ! La plupart du temps il suffisait de mettre des exceptions en plus.
Cependant...

Wojnicz a écrit:

Quand une suite *Cja ou *Cwa suit directement un marqueur de prosodie, ça donne /Cⁱa/ et /Cᵘa/ au lieu de /Cʲa/ et /Cʷa/, de plus le marqueur de prosodie n'est pas effacé.

Citation :: ʲtwa => ʲtᵘa
ʲrwark => ʲrᵘarkʲə

... J'ai eu du mal à trouver ce qui clochait, surtout que ʲkwa => kʷa fonctionnait parfaitement.
En fait, c'est que les labiovélaires étaient explicitement définies dans la liste des consonnes, pas les autres consonnes labialisées inhérentes, du coup, la règle @cons => [-pal -lab] (consonne perd le trait "labialisation ou palatalisation prosodique") ne pouvait pas s'appliquer à ʲtᵘa, puisque tᵘ n'était pas une "consonne". Pour résoudre ceci j'ai rendu les diacritiques de marqueurs inhérents "flottants", c'est à dire que leur présence ne crée pas un symbole distinct et le logiciel comprend alors que tᵘ est la consonne /t/ déjà définie, plus un diacritique.

***

Bref, voici le fichier corrigé avec moult commentaires :

Code:: #Palatalisation prosodique
Feature +lab, +pal
#Palatalisation inhérente
Feature +inlab, +inpal
#Ce trait n'est pertinent que pour les vélaires
Feature manner(occl, nas, fric)

#On déclare des diacritiques distinctes pour prosodique et inhérente
#Elles sont "flottantes" pour ne pas bloquer les changements qui ne les mentionnent pas explicitement
Diacritic ᵒ (floating) (before) [+lab]
Diacritic ᵉ (floating) (before) [+pal]
Diacritic ᵘ (floating) [+inlab]
Diacritic ⁱ (floating) [+inpal]

#Ces trois symboles déclarés explicitement car digraphes
Symbol kʷ [occl +inlab]
Symbol ŋʷ [nas +inlab]
Symbol xʷ [fric +inlab]
#Ceux-ci déclarés pour une meilleure intégration aux règles impliquant les précédents
Symbol k [occl]
Symbol ŋ [nas]
Symbol x [fric]

Class cons {p, t, k, kʷ, m, n, ŋ, ŋʷ, ɸ, θ, s, x, xʷ, l, r, w, j, ʔ}
Class glide {j, w}
Class labiovelar {kʷ, ŋʷ, xʷ}
Class plainvelar {k, ŋ, x}
Class obstruent {p, t, k, kʷ, ɸ, θ, x, xʷ}
Class stop {p, t, k, kʷ}
Class fricative {ɸ, θ, x, xʷ}
Class nasal {m, n, ŋ, ŋʷ}
Class coda {m, n, ŋ, ŋʷ, s, l, r}
Class vow {a, ə}

#On sépare les ʷ des labiovélaires des ʷʲ de début de mot/suffixe
Deromanizer:
@plainvelar ʷ => @labiovelar *
ʷ [] => * [+lab] / {\-, $} _
ʲ [] => * [+pal] / {\-, $} _

#Toutes les consonnes reçoivent un schwa sauf devant <a>
epenthesis:
* => ə / @cons _ // _ a

#Suppression schwa après diphtongue et consonne coda (sauf si seule consonne du mot)
deletion-final:
ə => * / {@coda, j, w} _ $ // $ [] _

#Suppression schwa pour former groupes initiaux autorisés (sauf si liquide termine le mot)
deletion-initial:
ə => * / $ @obstruent _ {l, r} // _ [] $
ə => * / $ s _ @stop&!ʔ

#Suppression schwa pour former groupes médians autorisés (sauf si le groupe serait devant un segment final)
deletion-middle propagate ltr:
ə => * / @vow @obstruent _ {l, r} // _ [] $
ə => * / @vow s _ @stop&!ʔ // _ [] $
ə => * / @vow @nasal _ @stop // _ [] $
ə => * / @vow {@nasal, l, r} _ @cons&!ʔ // _ [] $
ə => * / @vow @stop _ s // _ [] $
ə => * / @vow s _ {@nasal, l, r} // _ [] $
ə => * / @vow @cons$1 _ $1 // _ [] $
ə => * / @vow @labiovelar&[$manner] _ @plainvelar&[$manner] // _ [] $

#Suppression schwa surnuméraires dans diphtongues
deletion-diphtongs:
ə => * / @cons _ @glide a // _ [] [] {w, j}
ə => * / @vow @glide _

#Voici la première règle formulée dans Lexurgy exactement comme Wojnicz l'avait formulée en clair
delabialisation:
ŋʷ => ŋ / _ $
@labiovelar => @plainvelar / _ @cons

#D'autres segments que les vélaires reçoivent le trait "lab/pal inhérente"
inherent-lab-pal:
@cons j => [+inpal] * / _ a
@cons w => [+inlab] * / _ a

#Le marqueur prosodique se déplace à la fin du mot sauf s'il y a déjà un suffixe avec marqueur prosodique
prosodic-pal-lab-to-end:
[-lab -pal -inpal -inlab] => [+lab] / $ [+lab] []* _ $ // {[+lab], [+pal]} _
[-lab -pal -inpal -inlab] => [+pal] / $ [+pal] []* _ $ // {[+lab], [+pal]} _

#En partant de la fin chaque voyelle reçoit son marqueur prosodique sauf si elle est devant une consonne à marque inhérente ou fait partie d'une diphtongue
prosodic-lab-pal propagate rtl:
@vow => [+lab] /_ []* [+lab] // {{[+inlab], [+inpal]} _, _ @glide}
@vow => [+pal] /_ []* [+pal] // {{[+inlab], [+inpal]} _, _ @glide}
#Ça c'est pour pas oublier de marquer les voyelle placées après les suffixes à marqueur
@vow => [+lab] / [+lab] _ $
@vow => [+pal] / [+pal] _ $

#Marqueurs prosodiques après inhérents et glides, devant consonne, et tirets, supprimés
Romanizer:
@vow => [-pal -lab] / {[+inlab], [+inpal], @glide} _
@cons => [-pal -lab]
\- => *
#On remet les diacritiques de départ confondant prosodique et inhérente
Then:
* [+pal] => ʲ [-pal]
* [+lab] => ʷ [-lab]
[+inpal] * => [-inpal] ʲ
[+inlab] * => [-inlab] ʷ

Messages : 850 Date d'inscription : 13/12/2017

J'ai testé avec une autre centaine de racines, un sans-faute, félicitations! Souhaites-tu que j'envoie ton programme à la cliente et que je lui demande de te créditer?

En tout cas, tu as gagné un mot dans le lexique à ta gloire, pourquoi pas curan (*/kwrn/ => */kəwrən/ => /kuran/)? Je le verrais bien vouloir dire "oser", parce que tu as osé là où je ne l'ai pas fait, qu'est-ce que tu en penses?

Sujet: Re: Le levostis Dim 16 Oct 2022 - 0:56

Le mot je l'accepte sans réserve ! Me voilà curnus "celui qui ose".
Oui, je lâche ce programme dans la nature, j'espère que la cliente le trouvera utile ! Et si c'est le cas, un petit crédit à mon pseudo sera bienvenu.

J'ai beaucoup aimé faire ça, encore une fois je trouve que c'est une langue joliment faite. Si je n'avais pas peur de me disperser en ce moment je bricolerais bien des levostides en mode pseudo-germanique, pseudo-slave, etc.

Messages : 850 Date d'inscription : 13/12/2017

J'ai bien peur d'avoir encore trouvé des failles, ça vient en partie d'un manque d'explications de ma part et du fait que j'ai testé avec des racines seules, mais que je n'ai pas pensé à le faire en leur ajoutant des affixes, c'est là que ça coince.

Premièrement, je n'ai pas précisé un point important du proto-levostis concernant ses préfixes donc tu ne pouvais pas savoir: si on ajoute à une racine commençant par *ʔ un préfixe finissant par une consonne, cette consonne remplace *ʔ. C'est pour ça que adra donne hadra, c'est parce qu'on est parti de *ʔaθra et que quand on lui ajoute le préfixe *x-, ça donne *xaθra. Du coup, le programme, lui, il donne /xəʔaθra/. Ma faute.

Deuxièmement, si j'ajoute des préfixes finissant par une consonne à des racines commençant par une consonne, le programme ne déclenche pas la resyllabification et ajoute un schwa même là où il ne devrait pas y en avoir un:

Citation :: x-rʔan => xərəʔan
s-rksa => sərəksa
Note que le programme ne fait pas cette erreur si je mets le préfixe sans tiret:
xrʔan => xrəʔan
srksa => sərkəsa

Troisièmement, le même problème a lieu avec les suffixes quand je les ajoute à une racine finissant par une consonne, le programme ne déclenche pas la resyllabification et ajoute un schwa même là où il ne devrait pas y en avoir un:

Citation :: rksa-t-ra => rəksatəra
ʔaθra-wm => ʔaθrawəm
ʲlaxʷas-tj => lʲaxʷasʲətəj
Là encore, le programme ne fait pas cette erreur si je mets le suffixe sans tiret:
rksatra => rəksatra
ʔaθrawm => inchangé
ʲlaxʷastj => lʲaxʷastəj

Quatrièmement, j'ai vite fait mentionné ça mais ça a pu t'échapper:

Citation :: c'est toujours la labialisation ou palatalisation la plus à droite qui l'emporte

Le programme n'applique étrangement pas toujours ça s'il y a plusieurs suffixes à prosodie, du coup *maxl-ʷs-ʲs donne *mʷaxlʷəsʲəs au lieu de *mʲaxlʲəsʲəs, comme la prosodie la plus à droite l'emporte, la palatalisation devrait remplacer la labialisation dans tout le mot.

Cinquièmement, une autre règle que j'ai rapidement mentionné est celle-là:

Citation :: Quand /j w/ suivent une consonne et ne sont pas suivies de /a/, on ajoute un /ə/ avant, donc /mjm/ donne /məjm/.

Le programme ne l'applique pas toujours, pour des raisons qui m'échappent, /kaʔajrwm/ donne /kaʔajrwəm/ au lieu de /kaʔajrəwm/.

Sujet: Re: Le levostis Dim 16 Oct 2022 - 12:03

Encore une fois mon lexique de test n'était pas assez diversifié... j'ai repéré le problème avec la prosodie des suffixes et les tirets tout de suite après avoir reçu mon mot, ça et les autres corrections j'ai l'impression que l'écriture du programme devient légèrement moins gazeuse.

Code:: #Palatalisation prosodique
Feature prosody(*plain, lab, pal)
#Palatalisation inhérente
Feature +inlab, +inpal
#Ce trait n'est pertinent que pour les vélaires
Feature manner(occl, nas, fric)

#On déclare des diacritiques distinctes pour prosodique et inhérente
#Elles sont sont "flottantes" pour ne pas bloquer les changements qui ne les mentionnent pas explicitement
Diacritic ᵒ (floating) (before) [lab]
Diacritic ᵉ (floating) (before) [pal]
Diacritic ᵘ (floating) [+inlab]
Diacritic ⁱ (floating) [+inpal]

#Ces trois symboles déclarés explicitement car digraphes
Symbol kʷ [occl +inlab]
Symbol ŋʷ [nas +inlab]
Symbol xʷ [fric +inlab]
#Ceux-ci déclarés pour une meilleure intégration aux règles impliquant les précédents
Symbol k [occl]
Symbol ŋ [nas]
Symbol x [fric]

#Définition élément réunissant voyelles et diphtongues
Element sybic {@vow, @vow @glide}

Class cons {p, t, k, kʷ, m, n, ŋ, ŋʷ, ɸ, θ, s, x, xʷ, l, r, w, j, ʔ}
Class glide {j, w}
Class labiovelar {kʷ, ŋʷ, xʷ}
Class plainvelar {k, ŋ, x}
Class obstruent {p, t, k, kʷ, ɸ, θ, x, xʷ}
Class stop {p, t, k, kʷ}
Class fricative {ɸ, θ, x, xʷ}
Class nasal {m, n, ŋ, ŋʷ}
Class coda {m, n, ŋ, ŋʷ, s, l, r}
Class vow {a, ə}

#On sépare les ʷ des labiovélaires des ʷʲ de début de mot/suffixe
Deromanizer:
@plainvelar ʷ => @labiovelar *
ʷ [] => * [lab] / {\-, $} _
ʲ [] => * [pal] / {\-, $} _

#Schwa disparaît après préfixe consonantique, puis tirets s'en vont
hamza-black-magic:
ʔ => * / $ @cons \- _
\- => *

#Toutes les consonnes reçoivent un schwa sauf devant <a>
epenthesis:
* => ə / @cons _ // _ a

#Suppression schwa après diphtongue et consonne coda (sauf si seule consonne du mot)
deletion-final:
ə => * / {@coda, j, w} _ $ // $ [] _

#Suppression schwa pour former groupes initiaux autorisés (sauf si liquide termine le mot)
deletion-initial:
ə => * / $ @obstruent _ {l, r} // _ [] $
ə => * / $ s _ @stop

#Suppression schwa surnuméraires dans diphtongues
deletion-diphtongs:
ə => * / @cons _ @glide a // _ [] [] {w, j}
ə => * / @vow @glide _

#Suppression schwa pour former groupes médians autorisés (sauf si le groupe serait devant un segment final)
deletion-middle propagate ltr:
ə => * / @sybic @obstruent _ {l, r} // _ [] $
ə => * / @sybic s _ @stop // _ [] $
ə => * / @sybic @nasal _ @stop // _ [] $
ə => * / @sybic {@nasal, l, r} _ @cons&!ʔ // _ [] $
ə => * / @sybic @stop _ s // _ [] $
ə => * / @sybic s _ {@nasal, l, r} // _ [] $
ə => * / @sybic @cons$1 _ $1 // _ [] $
ə => * / @sybic @labiovelar&[$manner] _ @plainvelar&[$manner] // _ [] $

#Voici la première règle formulée dans Lexurgy exactement comme Wojnicz l'avait formulée en clair
delabialisation:
ŋʷ => ŋ / _ $
@labiovelar => @plainvelar / _ @cons

#D'autres segments que les vélaires reçoivent le trait "lab/pal inhérente"
inherent-lab-pal:
@cons j => [+inpal] * / _ a
@cons w => [+inlab] * / _ a

#Le marqueur prosodique se déplace à la fin du mot sauf s'il y a déjà un suffixe avec marqueur prosodique
prosodic-marker-to-end:
[plain -inpal -inlab] => [lab] / $ [lab] [plain]* _ $
[plain -inpal -inlab] => [pal] / $ [pal] [plain]* _ $
#Suppression des marqueurs prosodiques situés à gauche du dernier marqueur prosodique
Then:
[!plain] => [plain] / _ []* [!plain]

#En partant de la fin chaque voyelle reçoit son marqueur prosodique sauf si elle est devant une consonne à marque inhérente ou fait partie d'une diphtongue
prosodic-marker propagate rtl:
@vow => [lab] /_ []* [lab] // {{[+inlab], [+inpal]} _, _ @glide}
@vow => [pal] /_ []* [pal] // {{[+inlab], [+inpal]} _, _ @glide}
#Ça c'est pour pas oublier de marquer les voyelle placées après les suffixes à marqueur
@vow => [lab] / [lab] _
@vow => [pal] / [pal] _

#Marqueurs prosodiques après inhérents et glides, et devant consonne, supprimés
Romanizer:
@vow => [plain] / {[+inlab], [+inpal], @glide} _
@cons => [plain]
#On remet les diacritiques du début confondant prosodique et inhérente
Then:
* [pal] => ʲ [plain]
* [lab] => ʷ [plain]
[+inpal] * => [-inpal] ʲ
[+inlab] * => [-inlab] ʷ

Sinon, ce serait quoi la dérivation agent animé de */kwrn/ et ses formes liée et non-possédée en proto-langue ? D'après ce que j'ai cru comprendre des suffixes anciens, ce serait *kwrn-ʷs, *kwrn-ʷs-ra, *kwrn-ʷs-ʲs, donnant en levostis curnus, curnurra, curniris

Messages : 850 Date d'inscription : 13/12/2017

Exact, *kwrn-ʷs donne */kəwrnʷəs/ puis /kurnus/ (curnus), *kwrn-ʷs-ra donne */kəwrnʷəsra/ puis /kurnurra/ (curnurra), et *kwrn-ʷs-ʲs donne */kəwrnʲəsʲəs/ puis /kurniris/ (curniris).

J'ai testé 50 mots sans affixes et 50 mots avec. Pour ceux sans affixes, un quasi-sans-faute, le seul qui n'a pas marché, c'est celui-là:

Citation :: ʷθamwxʷ => θʷamwxʷə

Ce devrait être /θʷaməwxʷə/, le programme a encore oublié l'épenthèse avant une semivoyelle.

Pour ceux avec affixes, en revanche, il s'est raté pas mal de fois.

Premièrement, là encore, le programme oublie l'épenthèse avant semivoyelle:

Citation :: s-ʲtkajm-wm => stʲəkajmwm au lieu de stʲəkajməwm
kxʷakʷar-wm => kəxʷakʷarwm au lieu de kəxʷakʷarəwm

Deuxièmement, si on ajoute un préfixe à une racine commençant par un coup de glotte et qu'on efface donc le coup de glotte, ça efface aussi la prosodie:

Citation :: s-ʲʔatwa => satʷa au lieu de sʲatʷa

Troisièmement, un autre oubli d'épenthèse ici:

Citation :: naʔ-ʔ-ʷs => nʷaʔʔʷəs au lieu de nʷaʔʷəʔʷəs

Quatrièmement, le programme oublie parfois de propager la prosodie à la racine entière:

Citation :: s-ʷtk => stʷəkə au lieu de stʷəkʷə
x-ʷrasak-t => xrʷasakətə au lieu de xrʷasʷakʷətə
x-ʲmŋʷaxʷma => xʲəmŋʷaxʷəma au lieu de xʲəmŋʷaxʷəmʲa

Cinquièmement, un schwa en trop ici:

Citation :: ʷxa-ʔ-ʷs-sj-ʲs => xʲaʔʲəsʲəsəjs au lieu de xʲaʔʲəssəjs

Sixièmement, le programme a tendance à appliquer une prosodie aux suffixes sans prosodie comme *-ra, un suffixe n'est pas censé être affecté par la prosodie du mot le portant, à moins d'être suivi d'un autre suffixe portant lui-même une prosodie, comme *-ʲs.

Citation :: ʲxak-t => xʲakʲətʲə au lieu de xʲakʲətə
ʷɸxsam-ka => ɸʷəxʷəsʷamkʷa au lieu de ɸʷəxʷəsʷamka
ʲkaxʷpa-ra => kʲaxʷəpʲarʲa au lieu de kʲaxʷəpʲara
ʷnw-ʔ => nəwʔʷə au lieu de nəwʔə
ʲt-t-ra => tʲətrʲa au lieu de tʲətra
ʷxama-ra => xʷamʷarʷa au lieu de xʷamʷara
ʲrθa-ka => rʲəθʲakʲa au lieu de rʲəθʲaka
ʲxʷ-wm-ra => xʷəwmrʲa au lieu de xəwmra
ʷnθŋa-t => nʷəθʷəŋʷatʷə au lieu de nʷəθʷəŋʷatə

Septièmement, et là on entre dans un problème insoluble avec le programme sous sa forme actuelle, ce dernier ne fait pas la différence entre ajouter un préfixe finissant par une consonne à une racine commençant par *ʔ, et ajouter le suffixe *-ʔ (qui est le suffixe qui étend le sens d'un verbe, *aθra > *aθraʔ, d'où adra > adrá) à une racine finissant par une consonne. J'ai souligné quelle partie est la racine:

Citation :: ʷr-ʔ-wm => rəwm au lieu de rʷəʔəwm

Le programme prend *-ʔ pour la racine et l'efface alors que c'est un suffixe. Comme *x et *ʔ sont des racines valides toutes les deux, on peut se retrouver avec un cas comme *x-ʔ-ra, qui donne /xəʔəra/, contre *x-ʔ-ra, qui donne /xra/, le programme ne peut pas les différencier. Une possible solution serait de remplacer les tirets par des chevrons, ⟩ pour les préfixes et ⟨ pour les suffixes, donc le premier exemple serait x⟨ʔ⟨ra et le second x⟩ʔ⟨ra. Mais je ne sais pas si Lexurgy l'autorise.

Je suis navré de constamment te trouver de nouveaux problèmes. J'aurais dû garder cette phono pour un projet où le client ne veut pas inventer ses propres mots, c'est un calvaire technique.

Sujet: Re: Le levostis Mar 18 Oct 2022 - 12:05

Petite question comme ça, *ŋʷja doit-il donner ŋʷəja ou ŋʲa ? Je penche pour le premier.

Autrement, coquilles corrigées, mais... je bute sur le sixièmement et le septièmement, les problèmes découlent effectivement du découpage en affixe et racine.

Wojnicz a écrit:: Une possible solution serait de remplacer les tirets par des chevrons, ⟩ pour les préfixes et ⟨ pour les suffixes, donc le premier exemple serait x⟨ʔ⟨ra et le second x⟩ʔ⟨ra. Mais je ne sais pas si Lexurgy l'autorise.

Oui, tous les caractères sont possibles, il faut seulement échapper ceux qui ont un sens dans le programme en écrivant les règles (pas le lexique), par exemple en \- ou \:.

Wojnicz a écrit:: Je suis navré de constamment te trouver de nouveaux problèmes. J'aurais dû garder cette phono pour un projet où le client ne veut pas inventer ses propres mots, c'est un calvaire technique.

Oh, si elle y arrive à la main plus facilement, ce n'est pas tant un problème. Tu lui as fait faire des exercices pour voir si vous compreniez les instructions pareillement ?

Messages : 850 Date d'inscription : 13/12/2017

Citation :: Petite question comme ça, *ŋʷja doit-il donner ŋʷəja ou ŋʲa ? Je penche pour le premier.

Cette suite n'est pas permise, je l'ai mentionné page 1:

Citation :: Un squelette peut contenir la même consonne 2 fois d'affilée, mais jamais plus de 2, et ne peut jamais contenir les suites /ʔʔ ʔaʔ jj jaj ww waw/ ou toute suite consistant en une labio-vélaire suivie d'une semi-voyelle ou d'une diphtongue, comme /xʷj/.

Si une affixation provoquait l'apparition d'une suite pareille, la labiovélaire serait délabialisée.

Citation :: je bute sur le sixièmement et le septièmement

Même si tu n'y arrives vraiment pas, je peux t'assurer que ton mot restera, tu as osé et c'est l'important.

Citation :: Oh, si elle y arrive à la main plus facilement, ce n'est pas tant un problème. Tu lui as fait faire des exercices pour voir si vous compreniez les instructions pareillement ?

Non, comme elle m'a souvent dit qu'elle a peu de temps libre.

Sujet: Re: Le levostis Mar 18 Oct 2022 - 14:27

D'ailleurs, pour la génération des squelettes, c'est automatisé aussi ?

Sujet: Re: Le levostis Mar 18 Oct 2022 - 17:53

"sixièmement", sur le non-déplacement de la prosodie sur les suffixes, a été résolu au prix d'une augmentation du volume gazeux.

La règle morphophonologique de chute de la glottale devant préfixe consonantique a été retirée du programme (on aura donc toujours x-ʔ => xəʔə. J'ai bien peur qu'il ne faille continuer à le faire à la main, en précisant les modalités.

Code:: #Palatalisation prosodique
Feature prosody(*plain, lab, pal)
#Palatalisation inhérente
Feature inherent(*invoid, inlab, inpal)
#Ce trait n'est pertinent que pour les vélaires
Feature manner(occl, nas, fric)
Feature +affix

#On déclare des diacritiques distinctes pour prosodique et inhérente, et pour le tiret
#Elles sont sont "flottantes" pour ne pas bloquer les changements qui ne les mentionnent pas explicitement
Diacritic ᵒ (floating) (before) [lab]
Diacritic ᵉ (floating) (before) [pal]
Diacritic ᵘ (floating) [inlab]
Diacritic ⁱ (floating) [inpal]
Diacritic \- (floating) [+affix]

#Ces trois symboles déclarés explicitement car digraphes
Symbol kʷ [occl inlab]
Symbol ŋʷ [nas inlab]
Symbol xʷ [fric inlab]
#Ceux-ci déclarés pour une meilleure intégration aux règles impliquant les précédents
Symbol k [occl]
Symbol ŋ [nas]
Symbol x [fric]

#Définition élément réunissant voyelles et diphtongues
Element sybic {@vow, @vow @glide}

Class cons {p, t, k, kʷ, m, n, ŋ, ŋʷ, ɸ, θ, s, x, xʷ, l, r, w, j, ʔ}
Class glide {j, w}
Class labiovelar {kʷ, ŋʷ, xʷ}
Class plainvelar {k, ŋ, x}
Class obstruent {p, t, k, kʷ, ɸ, θ, x, xʷ}
Class stop {p, t, k, kʷ}
Class fricative {ɸ, θ, x, xʷ}
Class nasal {m, n, ŋ, ŋʷ}
Class coda {m, n, ŋ, ŋʷ, s, l, r}
Class vow {a, ə}

#On sépare les ʷ des labiovélaires des ʷʲ de début de mot/suffixe
Deromanizer:
ʷ [] => * [lab] / {[+affix], $} _
ʲ [] => * [pal] / {[+affix], $} _

#Toutes les consonnes reçoivent un schwa sauf devant <a>
epenthesis:
* => ə / @cons _ // _ a

#Suppression schwa après diphtongue et consonne coda (sauf si seule consonne du mot)
deletion-final:
ə => * / {@coda, j, w} _ $ // $ [] _

#Suppression schwa pour former groupes initiaux autorisés (sauf si liquide termine le mot)
deletion-initial:
ə => * / $ @obstruent _ {l, r} // _ [] $
ə => * / $ s _ @stop

#Suppression schwa surnuméraires dans diphtongues
deletion-diphtongs:
ə => * / @cons _ @glide a // _ [] [] {w, j}
ə => * / @vow @glide _

#Suppression schwa pour former groupes médians autorisés (sauf si le groupe serait devant un segment final)
deletion-middle propagate ltr:
ə => * / @sybic @obstruent _ {l, r} // _ [] $
ə => * / @sybic s _ @stop // _ [] $
ə => * / @sybic @nasal _ @stop // _ [] $
ə => * / @sybic {@nasal, l, r} _ @cons&!{ʔ, @glide} // _ [] $
ə => * / @sybic @stop _ s // _ [] $
ə => * / @sybic s _ {@nasal, l, r} // _ [] $
ə => * / @sybic @cons$1 _ ~$1&!ʔ // _ [] $
ə => * / @sybic @labiovelar&[$manner] _ @plainvelar&[$manner] // _ [] $

#Voici la première règle formulée dans Lexurgy exactement comme Wojnicz l'avait formulée en clair
delabialisation:
ŋʷ => [invoid] / _ $
@labiovelar => @plainvelar / _ @cons

#D'autres segments que les vélaires reçoivent le trait "lab/pal inhérente"
inherent-lab-pal:
@cons&[invoid] j => [inpal] * / _ a
@cons&[invoid] w => [inlab] * / _ a

#Le marqueur prosodique se déplace à la fin du mot
#sauf s'il y a déjà un suffixe avec marqueur prosodique
#et s'il y a déjà deux tirets avant
prosodic-marker-to-end:
[plain invoid] => [lab] / {$, [+affix]} [lab] [-affix]* _ // [+affix] []* [+affix] []* _
[plain invoid] => [pal] / {$, [+affix]} [pal] [-affix]* _ // [+affix] []* [+affix] []* _
#Suppression des marqueurs prosodiques situés à gauche du dernier marqueur prosodique
Then:
[!plain] => [plain] / _ []* [!plain]

#En partant de la fin chaque voyelle reçoit son marqueur prosodique sauf si elle est devant une consonne à marque inhérente ou fait partie d'une diphtongue
prosodic-marker propagate rtl:
@vow => [lab] /_ []* [lab] // {[!invoid] _, _ @glide}
@vow => [pal] /_ []* [pal] // {[!invoid] _, _ @glide}
#Ça c'est pour pas oublier de marquer les voyelle placées après les suffixes à marqueur
@vow => [lab] / [lab] _ !@glide
@vow => [pal] / [pal] _ !@glide

#Marqueurs prosodiques après inhérents et glides, et devant consonne, supprimés
Romanizer:
@vow => [plain] / {[!invoid], @glide} _
@cons => [plain]
#On remet les diacritiques du début confondant prosodique et inhérente
Then:
* [pal] => ʲ [plain]
* [lab] => ʷ [plain]
[inpal] * => [invoid] ʲ
[inlab] * => [invoid] ʷ
#Suppression tirets
Then:
[+affix] => [-affix]

Messages : 850 Date d'inscription : 13/12/2017

Citation :: D'ailleurs, pour la génération des squelettes, c'est automatisé aussi ?

Oui, avec ce générateur et les paramètres ci-dessous: https://chridd.nfshost.com/makewords/

Code:: WORD = I | I C | I C C | I C C C
I = P c v
C = c v
P = ʲ | ʷ | EMPTY
c = m | n | ŋ | N | p | t | k | K | ʔ | ɸ | θ | x | X | s | l | j | w | r
v = a | EMPTY
AVOID mmm
AVOID nnn
AVOID ŋŋŋ
AVOID NNN
AVOID ppp
AVOID ttt
AVOID kkk
AVOID KKK
AVOID ʔʔ
AVOID ʔaʔ
AVOID ɸɸɸ
AVOID θθθ
AVOID xxx
AVOID XXX
AVOID sss
AVOID lll
AVOID jj
AVOID jaj
AVOID ww
AVOID waw
AVOID rrr
AVOID Nj
AVOID Kj
AVOID Xj
AVOID Naj
AVOID Kaj
AVOID Xaj
AVOID Nw
AVOID Kw
AVOID Xw
AVOID Naw
AVOID Kaw
AVOID Xaw
REPLACE N ŋʷ
REPLACE K kʷ
REPLACE X xʷ

Citation :: La règle morphophonologique de chute de la glottale devant préfixe consonantique a été retirée du programme (on aura donc toujours x-ʔ => xəʔə. J'ai bien peur qu'il ne faille continuer à le faire à la main, en précisant les modalités.

Le truc des chevrons n'a pas marché?